delphi英文數(shù)字轉(zhuǎn)中文數(shù)字的辦法

(*//
標(biāo)題:中文數(shù)字表達(dá)
說明:普通方式和貨幣方式;和其它算法思路不一樣;建議參考比較一下
設(shè)計:Zswang
日期:2002-01-25
支持:wjhu111@21cn.com
//*)

///////Begin Source
function NumberCn(mNumber: Real): WideString;
const
  cPointCn: WideString =  '點十百千萬十百千億十百千';
  cNumberCn: WideString =  '零一二三四五六七八九';
var
  I, L, P: Integer;
  S: string;
begin
  Result := '';
  if mNumber = 0 then begin
    Result := cNumberCn[1];
    Exit;
  end;
  S := FloatToStr(mNumber);
  if Pos('.', S) <= 0 then S := S + '.';
  P := Pos('.', S);
  L := Length(S);
  for I := 1 to L do
    if P > I then
      Result := Result + cNumberCn[StrToInt(S[I]) + 1] + cPointCn[P - I]
    else if P = I then begin
      Result := StringReplace(Result, '零十零', '零', [rfReplaceAll]);
      Result := StringReplace(Result, '零百零', '零', [rfReplaceAll]);
      Result := StringReplace(Result, '零千零', '零', [rfReplaceAll]);
      Result := StringReplace(Result, '零十', '零', [rfReplaceAll]);
      Result := StringReplace(Result, '零百', '零', [rfReplaceAll]);
      Result := StringReplace(Result, '零千', '零', [rfReplaceAll]);
      Result := StringReplace(Result, '零萬', '萬', [rfReplaceAll]);
      Result := StringReplace(Result, '零億', '億', [rfReplaceAll]);
      Result := StringReplace(Result, '億萬', '億', [rfReplaceAll]);
      Result := StringReplace(Result, '零點', '點', [rfReplaceAll]);
    end else if P < I then
      Result := Result + cNumberCn[StrToInt(S[I]) + 1];
  if Result[Length(Result)] = cPointCn[1] then
    Result := Copy(Result, 1, Length(Result) - 1);
  if Result[1] = cPointCn[1] then Result := cNumberCn[1] + Result;
  if (Length(Result) > 1) and (Result[2] = cPointCn[2]) and
    (Result[1] = cNumberCn[2]) then
    Delete(Result, 1, 1);
end; { NumberCn }

function MoneyCn(mMoney: Real): WideString;
var
  P: Integer;
begin
  if mMoney = 0 then begin
    Result := '無';
    Exit;
  end;
  Result := NumberCn(Round(mMoney * 100) / 100);
  Result := StringReplace(Result, '一', '壹', [rfReplaceAll]);
  Result := StringReplace(Result, '二', '貳', [rfReplaceAll]);
  Result := StringReplace(Result, '三', '叁', [rfReplaceAll]);
  Result := StringReplace(Result, '四', '肆', [rfReplaceAll]);
  Result := StringReplace(Result, '五', '伍', [rfReplaceAll]);
  Result := StringReplace(Result, '六', '陸', [rfReplaceAll]);
  Result := StringReplace(Result, '七', '柒', [rfReplaceAll]);
  Result := StringReplace(Result, '八', '捌', [rfReplaceAll]);
  Result := StringReplace(Result, '九', '玖', [rfReplaceAll]);
  Result := StringReplace(Result, '九', '玖', [rfReplaceAll]);
  Result := StringReplace(Result, '十', '拾', [rfReplaceAll]);
  Result := StringReplace(Result, '百', '佰', [rfReplaceAll]);
  Result := StringReplace(Result, '千', '仟', [rfReplaceAll]);
  P := Pos('點', Result);
  if P > 0 then begin
    Insert('分', Result, P + 3);
    Insert('角', Result, P + 2);
    Result := StringReplace(Result, '點', '圓', [rfReplaceAll]);
    Result := StringReplace(Result, '角分', '角', [rfReplaceAll]);
    Result := StringReplace(Result, '零分', '', [rfReplaceAll]);
    Result := StringReplace(Result, '零角', '', [rfReplaceAll]);
    Result := StringReplace(Result, '分角', '', [rfReplaceAll]);
    if Copy(Result, 1, 2) = '零圓' then
      Result := StringReplace(Result, '零圓', '', [rfReplaceAll]);
  end else Result := Result + '圓整';
  Result := '人民幣' + Result;
end; { MoneyCn }
///////End Source

///////Begin Demo
procedure TForm1.Button1Click(Sender: TObject);
begin
  Edit1.Text := MoneyCn(StrToFloatDef(Edit3.Text, 0));
  Edit2.Text := NumberCn(StrToFloatDef(Edit3.Text, 0));
end;
///////End Demo